Windows licentiesleutel vinden

Het is een veelgestelde vraag onder computergebruikers: hoe vind ik mijn Windows licentiecode? Het kennen van deze code, ook wel productsleutel of licentiesleutel genoemd, is essentieel in verschillende situaties.

Waarom is uw Windows licentiecode belangrijk?

1. Herinstallatie van Windows
   Als u Windows opnieuw wilt installeren, bijvoorbeeld na een systeemcrash of hardware-upgrade, heeft u de licentiecode nodig om het besturingssysteem te activeren.
2. Overzetten van een Windows-licentie
   Wanneer u een nieuwe computer koopt en een bestaande retaillicentie wilt overzetten, moet u de licentiecode kennen. Retaillicenties zijn overdraagbaar, maar vereisen de originele code om op een nieuw apparaat te activeren.
3. Controle van authenticiteit
   Bij aankoop van een tweedehands computer wilt u mogelijk controleren of de geïnstalleerde Windows-versie legitiem is. De licentiecode helpt u om te verifiëren dat u een originele versie gebruikt.
4. Technische ondersteuning
   Bij het oplossen van problemen of contact met klantenservice kan het nodig zijn om uw licentiecode te verstrekken.

Zoals u ziet, zijn er tal van redenen waarom het nuttig is om uw Windows licentiecode te kennen. Maar hoe kunt u deze vinden?

Windows licentiesleutel vinden

Om te beginnen opent u kladblok op uw computer.

Kopieer en plak vervolgens het volgende scripts in een nieuw tekstdocument:

Option Explicit

Dim objshell,path,DigitalID, Result
Set objshell = CreateObject("WScript.Shell")
'Set registry key path
Path = "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\"
'Registry key value
DigitalID = objshell.RegRead(Path & "DigitalProductId")
Dim ProductName,ProductID,ProductKey,ProductData
'Get ProductName, ProductID, ProductKey
ProductName = "Product Name: " & objshell.RegRead(Path & "ProductName")
ProductID = "Product ID: " & objshell.RegRead(Path & "ProductID")
ProductKey = "Installed Key: " & ConvertToKey(DigitalID)
ProductData = ProductName & vbNewLine & ProductID & vbNewLine & ProductKey
'Show messbox if save to a file
If vbYes = MsgBox(ProductData & vblf & vblf & "Save to a file?", vbYesNo + vbQuestion, "BackUp Windows Key Information") then
Save ProductData
End If

'Convert binary to chars
Function ConvertToKey(Key)
Const KeyOffset = 52
Dim isWin8, Maps, i, j, Current, KeyOutput, Last, keypart1, insert
'Check if OS is Windows 8
isWin8 = (Key(66) \ 6) And 1
Key(66) = (Key(66) And &HF7) Or ((isWin8 And 2) * 4)
i = 24
Maps = "BCDFGHJKMPQRTVWXY2346789"
Do
Current= 0
j = 14
Do
Current = Current* 256
Current = Key(j + KeyOffset) + Current
Key(j + KeyOffset) = (Current \ 24)
Current=Current Mod 24
j = j -1
Loop While j >= 0
i = i -1
KeyOutput = Mid(Maps,Current+ 1, 1) & KeyOutput
Last = Current
Loop While i >= 0

If (isWin8 = 1) Then
keypart1 = Mid(KeyOutput, 2, Last)
insert = "N"
KeyOutput = Replace(KeyOutput, keypart1, keypart1 & insert, 2, 1, 0)
If Last = 0 Then KeyOutput = insert & KeyOutput
End If

ConvertToKey = Mid(KeyOutput, 1, 5) & "-" & Mid(KeyOutput, 6, 5) & "-" & Mid(KeyOutput, 11, 5) & "-" & Mid(KeyOutput, 16, 5) & "-" & Mid(KeyOutput, 21, 5)

End Function
'Save data to a file
Function Save(Data)
Dim fso, fName, txt,objshell,UserName
Set objshell = CreateObject("wscript.shell")
'Get current user name
UserName = objshell.ExpandEnvironmentStrings("%UserName%")
'Create a text file on desktop
fName = "C:\Users\" & UserName & "\Desktop\WindowsKeyInfo.txt"
Set fso = CreateObject("Scripting.FileSystemObject")
Set txt = fso.CreateTextFile(fName)
txt.Writeline Data
txt.Close
End Function

Bron.

Klik op “bestand” en vervolgens op “opslaan als”.

Wijzig “Opslaan als” naar “Alle bestanden”. Sla het bestand op als bestandsnaam “licentiecode.vbs”. Klik op de knop “Opslaan”.

U ziet nu op de locatie waar u licentiecode.vbs heeft opgeslagen een script. Dubbelklik erop om te openen. U ziet nu:

• Product Name. Dit is de Windows versie die u heeft geïnstalleerd. Houd er rekening mee dat als u Windows 10 heeft bijgewerkt naar Windows 11 er vaak nog Windows 10 staat.
• Product ID: Dit is het product-id die automatisch alleen voor uw computer is gegenereerd tijdens installatie. Dit ID is gebaseerd op de licentiesleutel.
• Installed Key: Dit is uw licentiesleutel. Hiermee kunt u Windows opnieuw installeren, activeren en meer.

Eventueel kunt u deze informatie nog opslaan naar een bestand door op “Ja” te klikken. U heeft op deze manier altijd uw licentiesleutel informatie beschikbaar.

Dit is een gratis en vooral makkelijke manier om uw licentiesleutel informatie op te zoeken. Deel uw licentiesleutel nooit met andere mensen, hooguit met Microsoft voor verificatie of ondersteuning.

Licentiecode niet gevonden? Dan vindt u de licentiesleutel mogelijk in de BIOS.

Ik hoop u hiermee geïnformeerd te hebben. Bedankt voor het lezen!